From Item to Index

In the preceding chapters, you have worked with ready-to-use indexes; now you will make them yourself. Instead of working online, you must download the data to your own computer. You are free to download the data in any of the available formats, but be aware that all syntax examples and explanations will be given with reference to SPSS.

Introductory comments to those using SPSS

First, you are recommended to organize your work the following way:

Download

Download the dataset in a format you are familiar with. You must decide if you would like to work with data from 2008 (ESS 4) or from 2002 (ESS 1). Please note that all examples and solutions will refer to 2002.

First round of preparation, cleaning and recoding

The purpose of the Portrait Values Questionnaire is to assess each respondent’s value priorities. Sometimes this is not possible, either because of missing data or because respondents use only one or a few response categories. Missing data make it difficult to assess value priorities accurately because there may be no items or only one that measures how important a particular value is to a respondent. Respondents who use only one or two points on the response scale to answer almost all items have probably not tried to make discriminations among values, so their responses do not reflect their actual priorities. If our aim were to evaluate the quality of the Portrait Values Questionnaire, we would want to examine the amount of missing data and the proportion of respondents who do not discriminate among the values. However, if our aim is to investigate substantive questions such as the associations of values with one another or with behaviour, attitudes, and background variables, it is better to drop those who did not respond to many value items or who did not discriminate in their responses to the value items.

  1. Compute a filter variable that identifies those who have more than 5 missing on the 21 value items, and those who have given the same answer to more than 16 of the 21 value items. Delete these respondents from the file.
    SPSS

    Open the file you downloaded in the first exercise. Paste the following syntax into a new syntax window (Open a new syntax window: File – New – Syntax.). Then you should run the syntax.

    *This syntax eliminates 5822 respondents from the file.

    COMPUTE drop=0.
    COUNT
    count1 = ipcrtiv to impfun (1)/count2 = ipcrtiv to impfun (2)/count3 = ipcrtiv to impfun(3)/
    count4 = ipcrtiv to impfun (4)/count5 = ipcrtiv to impfun (5)/count6 = ipcrtiv to impfun (6)/
    countmis = ipcrtiv to impfun (SYSMIS,7,8,9).
    if (max(count1 to count6)>16 or countmis>5) drop=1.
    value labels drop 0 'keep' 1 'drop'.
    execute.
    *Unselected cases are deleted from the file.
    FILTER OFF.
    USE ALL.
    SELECT IF(drop = 0).
    EXECUTE.
  2. Frequency
    Have a look at the frequencies for the variables "Ipmodst" and "Ipfrule". SPSS

    You could either generate the syntax by clicking through the menu (Analyse – Descriptive statistics – Frequencies) and pasting it into a syntax window, or by writing the syntax into a syntax window.

    FREQUENCIES
    VARIABLES = ipmodst ipfrule
    /ORDER= ANALYSIS.
    EXECUTE.
  3. Recode
    The “Ipmodst” and “Ipfrule” variables are, like all of the value items, coded with 1 representing “very much like me” and 6 “not like me at all”. It is more intuitive that a large number represents “very much like me”, and a low number represents “not like me” (large number = much of something, low number = little of something). Reverse the coding of all the value items (old code 1 = new code 6, old code 2 = new code 5, etc.). SPSS

    You are going to create 21 new variables with exactly the same information as the 21 original ones. The only difference is that the coding of the valid values is reversed. The proper command is recode. If you use the menu, you will have to repeat the procedure for each variable (Transform – Recode – Into different variables); by writing syntax you can do your work a lot faster. Each step is commented below.

    RECODE: List the original variables, define old and new codes in () (please note that the missing codes 7, 8, 9 are not changed). INTO: List the new variables (please note that the order of the new variables must be identical to the order of the original variables. The new variable names start with the letter n, to indicate that they are new.). The command FORMATS is used to decide the format of a variable. F1.0 means that the variable is numeric, one character long and with zero decimals. Because the variables are placed after each other in the data file, we can use “to” (from the first to the last). The command VARIABLE LABELS adds labels to the newly created variables. The command VALUE LABELS adds labels to the newly created codes. Because the labels are identical, we only need to write them once. This gives the following syntax:

    RECODE
    ipcrtiv imprich ipeqopt ipshabt impsafe impdiff ipfrule ipudrst ipmodst ipgdtim impfree iphlppl ipsuces ipstrgv ipadvnt ipbhprp iprspot iplylfr impenv imptrad impfun (1=6) (2=5) (3=4) (4=3) (5=2) (6=1) (7=7) (8=8) (9=9)
    INTO nipcrtiv nimprich nipeqopt nipshabt nimpsafe nimpdiff nipfrule nipudrst nipmodst nipgdtim nimpfree niphlppl nipsuces nipstrgv nipadvnt nipbhprp niprspot niplylfr nimpenv nimptrad nimpfun.
    FORMATS nipcrtiv to nimpfun (f1.0).
    VARIABLE LABELS
    nipcrtiv 'Important to think new ideas and being creative'
    nimprich 'Important to be rich, have money and expensive things'
    nipeqopt 'Important that people are treated equally and have equal opportunities'
    nipshabt 'Important to show abilities and be admired'
    nimpsafe 'Important to live in secure and safe surroundings'
    nimpdiff 'Important to try new and different things in life'
    nipfrule 'Important to do what is told and follow rules'
    nipudrst 'Important to understand different people'
    nipmodst 'Important to be humble and modest, not draw attention'
    nipgdtim 'Important to have a good time'
    nimpfree 'Important to make own decisions and be free'
    niphlppl 'Important to help people and care for others well-being'
    nipsuces 'Important to be successful and that people recognize achievements'
    nipstrgv 'Important that government is strong and ensures safety'
    nipadvnt 'Important to seek adventures and have an exiting life'
    nipbhprp 'Important to behave properly'
    niprspot 'Important to get respect from others'
    niplylfr 'Important to be loyal to friends and devote to people close'
    nimpenv 'Important to care for nature and environment'
    nimptrad 'Important to follow traditions and customs'
    nimpfun 'Important to seek fun and things that give'.
    VALUE LABELS nipcrtiv to nimpfun 1 "Not like me at all" 2 "Not like me" 3 "A little like me" 4 "Somewhat like me" 5 "Like me" 6 "Very much like me" 7 "Refusal" 8 "Don't know" 9 "No answer".
    Missing values nipcrtiv to nimpfun (7 to 9).
    EXECUTE.

Indexes

To compute a score for each of the ten values for an individual, use the items that index it from Table 4.2. The items are numbered from 1 to 21. Items that measure the same value were spread throughout the survey rather than clustered together.

Table 4.2. Value, item number and variable name
Values Items in index Variable name
Conformity 7,16 nipfrule, nipbhprp
Tradition 9,20 nipmodst, nimptrad
Benevolence 12,18 niphlppl, niplylfr
Universalism 3,8,19 nipeqopt, nipudrst, nimpenv
Self-Direction 1,11 nipcrtiv, nimpfree
Stimulation 6,15 nimpdiff, nipadvnt
Hedonism 10,21 nipgdtim, nimpfun
Achievement 4,13 nipshabt, nipsuces
Power 2,17 nimprich, niprspot
Security 5,14 nimpsafe, nipstrgv

The score for each value is the mean of the raw ratings given to the items listed in table 4.2 for that value. You could compute these means in two different ways. You could either add the items together and divide the sum by the number of items, for example; Security = (nimpsafe + nipstrgv) / 2, or you could use a function called MEAN. Using the first alternative, a respondent must have answered both questions to get a valid value on the index; the latter alternative will still compute a mean even if only one question is answered. The first method uses all items, and is thus more accurate. The second method ensures that as many as possible of the respondents get a valid value on the index.

  1. Create the indexes. You are recommended to use the MEAN function. Use the recoded variables. Later you are going to create another version of the indexes, so you must indicate either in the name or the label, that this is the first version. SPSS

    If you choose to use the menu, select “Transform – Compute”.

    Compute Apow = MEAN (nimprich, niprspot).
    Compute Apow = MEAN (nimprich, niprspot).
    Compute Aach = MEAN (nipshabt, nipsuces).
    Compute Ahed = MEAN (nimpfun, nipgdtim).
    Compute Asti = MEAN (nimpdiff, nipadvnt).
    Compute Aself = MEAN (nipcrtiv, nimpfree).
    Compute Auni = MEAN (nipeqopt, nipudrst, nimpenv).
    Compute Aben = MEAN (niphlppl, niplylfr).
    Compute Atra = MEAN (nipmodst, nimptrad).
    Compute Acon = MEAN (nipbhprp, nipfrule).
    Compute Asec = MEAN (nimpsafe, nipstrgv).
    EXECUTE.
    VARIABLE LABELS
    APow 'Power – mean of raw rating'
    Aach 'Achievement – mean of raw rating'
    Ahed 'Hedonism – mean of raw rating'
    Asti 'Stimulation – mean of raw rating'
    Aself 'Self-Direction – mean of raw rating'
    Auni 'Universalism – mean of raw rating'
    ABen 'Benevolence – mean of raw rating'
    Atra 'Tradition – mean of raw rating'
    ACon 'Conformity – mean of raw rating'
    ASec 'Security – mean of raw rating'.
    EXECUTE.
Go to next page >>