Exercise 5.1

To be able to solve this exercise, you need to have software (SPSS) installed on your computer, and you should download and use the dataset Family, Gender and Work.

  1. Denmark, Spain and the UK represent different regime types. Based on the logic of gender regime, in which country would you expect working women to experience the strongest family-work conflict? In which country would you expect the least work-family conflict?

Procedure:

Questions:

  1. What is the meaning of a high score for the variable you created?
  2. Do differences in mean scores for the family-work conflict variables conform to your hypothesis concerning country differences?
  3. Arrange the results of the regression analysis in a table consisting of three columns (one column for each country). The relevant coefficients for each variable should be listed in the rows.
  4. How is family-work conflict related to the number of hours women spend in market work and to the number of children?
SPSS syntax
*You need to have a copy of SPSS installed on your computer, and you should download and use the dataset Family, Gender and Work.
*Open SPSS by clicking on the appropriate link.
*Open the ESS data by clicking ‘File’, ‘Open’, and ‘Data’ on the SPSS menu bar before you select the folder and the data set.
*Open a new syntax window by clicking ‘File’, ‘New’, and ‘Syntax’ on the SPSS menu bar.
*You can copy the syntax below and paste it into the syntax window in SPSS.
*Execute the syntax using the 'Run' option on the menu bar.

*Comments on commands start with an asterisk and end with a dot.

*Commands must always end with a dot.

*The following command causes the cases to be weighted by the design weight variable 'dweight'.

WEIGHT BY dweight.

*Create filter variable - only include working women from Denmark, Spain and the UK living with partners.

USE ALL.
COMPUTE filter_$=gender = 0 & work_sta = 1 & (cntry ='DK' | cntry ='ES' | cntry ='GB' ) & (marital=1 or lvgptn=1).
VARIABLE LABEL filter_$ 'gender = 0 & work_sta = 1 & (cntry =DK or ES or GB) & (marital=1 or lvgptn=1) (FILTER)'.
VALUE LABELS filter_$ 0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE .
 
FACTOR
/VARIABLES wrywprb trdawrk jbprtfp pfmfdjb dfcnswk
/MISSING LISTWISE
/ANALYSIS wrywprb trdawrk jbprtfp pfmfdjb dfcnswk
/PRINT INITIAL EXTRACTION
/CRITERIA MINEIGEN(1) ITERATE(25)
/EXTRACTION PC
/ROTATION NOROTATE
/METHOD=CORRELATION.
 
RELIABILITY
/VARIABLES=wrywprb trdawrk jbprtfp pfmfdjb dfcnswk
/FORMAT=NOLABELS
/SCALE(ALPHA)=ALL/MODEL=ALPHA.
 
COMPUTE conflict = mean(wrywprb,trdawrk, jbprtfp, pfmfdjb, dfcnswk).
VARIABLE LABELS conflict 'Family-work conflict (index, MEAN wrywprb,trdawrk, jbprtfp, pfmfdjb, dfcnswk)'.
EXECUTE.
 
SORT CASES BY cntry.
SPLIT FILE LAYERED BY cntry.
 
DESCRIPTIVES
VARIABLES=conflict
/STATISTICS=MEAN STDDEV MIN MAX.
 
REGRESSION
/MISSING LISTWISE
/STATISTICS COEFF OUTS R ANOVA
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT conflict
/METHOD=ENTER partime children.

*Turn off the split file and weight, and select all cases.

SPLIT FILE OFF.
WEIGHT OFF.
USE ALL.
Sample solution

Problem

  1. Hypothesis: We expect working women to experience greatest work-family conflict in the market-dependence regime (UK) and least conflict in the individual-independence regime (Denmark).

Answers

  1. The factor analysis procedure (using principal component analysis) suggests that the five items represent one underlying factor, and their weights are rather similar. The relatively high reliability score (α = 0.77) also suggests that a composite score can be created. A high score on the scale indicates greater work-family conflict.
  2. Contrary to our hypothesis, the mean scores for the three countries are very similar.
  3. Table
  4. We use a dummy variable representing part-time vs. full-time employment and we find negative coefficients in all three countries (b = -0.158 for Denmark, b = -0.347 for Spain, and b = -0.395 for the UK). Working part-time (as opposed to full-time) reduces women’s perceived work-family conflict. The strongest effect, as might be expected, is in the UK. The number of young children at home does not generally have an effect on work-family conflict. Please note that the coefficient of Denmark (b = 0.146) is only borderline significant, indicating that more children tends to increase the conflict. The fact that the effect emerged in Denmark (rather than the UK) is contrary to expectations.