Chapter 4: Structural Equation Models

Example 2 on Structural equation modelling: The same model fitted separately for different countries

Fit the model considered in Example 1 separately for data from each of the countries in the ESS, and compare the results.

Stata commands:

// Fitting the same structural equation model separately for

// each country, and collecting some of the results in a table.

// After fitting the model for one country,

// as in the previous exercise, this command reveals the

// labels of the coefficients, which are used below:

sem, coeflegend // Reveal the coefficient labels, used below

//

levelsof cntry, clean local(countries)

local n_c: word count `countries'

matrix results = J(`n_c',8,.)

matrix rownames results = `countries'

matrix colnames results = bEff pbEff bFair ///

pbFair bObey pbObey bMoral pbMoral

local i = 0

foreach c of local countries {

local ++i

display "Country: " "`c'"

quietly: sem ///

(Effective -> plcpvcr plccbrg plcarcr) ///

(ProcFair -> plcrspc plcfrdc plcexdc) ///

if cntry=="`c'", ///

var(Effective@1) var(ProcFair@1) ///

method(mlmv)

matrix b=e(b)

quietly: sem ///

(Obey -> bplcdc doplcsy dpcstrb) ///

(MoralAlign -> plcrgwr plcipvl gsupplc) ///

if cntry=="`c'", ///

var(Obey@1) var(MoralAlign@1) ///

method(mlmv)

matrix b1=e(b)

matrix b=b,b1

quietly: sem ///

(Cooperation -> caplcst widprsn wevdct) ///

if cntry=="`c'", ///

var(Cooperation@1) ///

method(mlmv)

matrix b1=e(b)

matrix b=b,b1

sem ///

(Effective -> plcpvcr plccbrg plcarcr) ///

(ProcFair -> plcrspc plcfrdc plcexdc) ///

(Obey -> bplcdc doplcsy dpcstrb) ///

(MoralAlign -> plcrgwr plcipvl gsupplc) ///

(Cooperation -> caplcst widprsn wevdct) ///

(Effective ProcFair -> Obey MoralAlign) ///

(Effective ProcFair Obey MoralAlign -> Cooperation) ///

if cntry=="`c'", ///

var(Effective@1) var(ProcFair@1) ///

var(e.Obey@1) var(e.MoralAlign@1) var(e.Cooperation@1) ///

cov(e.Obey*e.MoralAlign) method(mlmv) ///

from(b,skip) iter(100) nolog satopts(nolog) baseopts(nolog)

//

local converged=e(converged)

if(`converged'==1){

matrix results[`i',1] = _b[Cooperation:Effective]

quietly: test _b[Cooperation:Effective]==0

matrix results[`i',2] = r(p)

matrix results[`i',3] = _b[Cooperation:ProcFair]

quietly: test _b[Cooperation:ProcFair]==0

matrix results[`i',4] = r(p)

matrix results[`i',5] = _b[Cooperation:Obey]

quietly: test _b[Cooperation:Obey]==0

matrix results[`i',6] = r(p)

matrix results[`i',7] = _b[Cooperation:MoralAlign]

quietly: test _b[Cooperation:MoralAlign]==0

matrix results[`i',8] = r(p)

}

}

//

matlist results, format(%7.3f)

Stata output and notes

# Fitting the same structural equation model separately for

# each country, and collecting some of the results in a table.

library(lavaan)

#

countries <- unique(ESS5Police$cntry)

results <- matrix(NA,length(countries),8)

rownames(results) <- countries

colnames(results) <- c("bEff","pbEff","bFair","pbFair","bObey","pbObey","bMoral","pbMoral")

#

ModelSyntax <- '

Effective =~ plcpvcr + plccbrg + plcarcr

ProcFair =~ plcrspc + plcfrdc + plcexdc

Obey =~ bplcdc + doplcsy + dpcstrb

MoralAlign =~ plcrgwr + plcipvl + gsupplc

Cooperation =~ caplcst + widprsn + wevdct

#

Obey + MoralAlign ~ Effective + ProcFair

Cooperation ~ Effective + ProcFair + Obey + MoralAlign

#

Obey ~~ MoralAlign

'

# Loop over the countries, and collect results:

i <- 0

for(cntry in countries){

i <- i+1

cat("Country: ", cntry, "\n")

FittedModel.sem <- sem(model = ModelSyntax,

data = ESS5Police[ESS5Police$cntry==cntry,],

std.lv = TRUE, meanstructure = TRUE,missing="ml")

print(summary(FittedModel.sem))

conv.tmp <- inspect(FittedModel.sem,"converged")

if(conv.tmp){

res.tmp <- parameterEstimates(FittedModel.sem)

res.tmp <- res.tmp[res.tmp$lhs=="Cooperation"&res.tmp$op=="~",]

results[i,1] <- res.tmp[res.tmp$rhs=="Effective","est"]

results[i,2] <- res.tmp[res.tmp$rhs=="Effective","pvalue"]

results[i,3] <- res.tmp[res.tmp$rhs=="ProcFair","est"]

results[i,4] <- res.tmp[res.tmp$rhs=="ProcFair","pvalue"]

results[i,5] <- res.tmp[res.tmp$rhs=="Obey","est"]

results[i,6] <- res.tmp[res.tmp$rhs=="Obey","pvalue"]

results[i,7] <- res.tmp[res.tmp$rhs=="MoralAlign","est"]

results[i,8] <- res.tmp[res.tmp$rhs=="MoralAlign","pvalue"]

}

}

print(round(results,3))

R output and notes

As one illustration of the results from this analysis, Table 4.1 shows the estimated regression coefficients and their levels of significance for the structural model for Co-operation with the police. Because these models were estimated separately for each of the countries rather than in one multigroup model, the scales of the latent variables are not here fixed to be comparable. The exact values of the regression coefficients can thus not be compared between the countries. However, we can compare the qualitative patterns of the results, for example the signs and levels of significance of the same coefficient in different countries.

There is a fair amount of variation in the levels of significance of the coefficients, in that each of the explanatory factors is a significant predictor of willingness to co-operate in many countries, but none of them in all countries. The variable which is significant in the largest number of countries is the person’s trust in the procedural fairness of the police. The directions of the associations are consistent in the sense that where a coefficient is significant it has the same sign in all the countries, with the one exception of trust in the effectiveness of the police which has a significantly negative coefficient in some countries and a significantly positive one in others.

Note: ***: p<0.001; **: p<0.01; *:p<0.05