Estimation of the unstandardized coefficients of the causal model

Given that Table 6.8 contains the covariances and variances corrected for measurement errors, the next step is now the same as that done in Chapter 5. In fact, the inputs for the programs are exactly the same except for the data we use as the starting point.

Figure 6.1: The causal model for the evaluation of democracy.

Below, we will illustrate how to run the estimation of the unstandardized coefficients of the causal model specified above (Figure 6.1) using both LISREL1 and Stata2. As both programs provide very similar results, please select which program you want to continue the analysis with.

Continue with LISREL

In Figure 6.2, all effects have been indicated using the symbols from LISREL. The betas (be) represent the effects of the explanatory (endogenous) variables (i.e. Free, Critic and Equal) on satisfaction with democracy (i.e. Satdem). For example, be(1,2) indicates the effect of the variable freedom and fairness of elections on satisfaction with democracy. Similarly, the gammas (ga) represent the effects of the control (exogenous) variables (i.e. LRplace and Inc) on the other variables in the model. For example, ga(1,1) indicates the effect of the control variable Left-right placement on satisfaction with democracy, while ga(3,2) indicates the effect of the other control variable, Income (i.e. Inc), on the variable equality by law (i.e. Equal). The effect of the variable Inc on Satdem is specified by a dashed line because it represents an effect that has been omitted because it was not significant in the analysis with correction for measurement errors.

Figure 6.2: The causal model for the evaluation of democracy with LISREL notation

We do not expect the control variables to completely explain the correlations that exist between the evaluation of democracy questions. We can therefore expect correlations between the disturbance terms (ζ24) of these variables. These correlations are not indicated in the model, but are denoted in LISREL by ps(3,2), ps(4,2) and ps(4,3), while the variances of the disturbances are denoted as ps(1,1), ps(2,2), ps(3,3) and ps(4,4). For details of the procedure, we refer to the LISREL manual [Jör96] and introductions to the program LISREL [Sar84]. First, the LISREL input for this analysis without corrections is presented in Syntax 6.1. Next, we present the same input corrected for measurement errors (see Syntax 6.2).

Syntax 6.1: The LISREL syntax for the estimation of the unstandardized coefficients of the causal model without correction for measurement errors*
Unstandardized causal analysis without corrections !Title
data ni=6 no=1468 ma=cm !ni=number of variables no=number of observations ma=matrix
cm !cm=covariance matrix
4.633
1.597 3.531
1.123 1.735 3.786
1.845 1.556 1.462 7.659
0.732 0.237 0.064 0.469 3.286
1.046 1.271 1.009 0.525 0.049 8.916
labels
satdem free critic equal lrplace inc !Labels of the variables
model ny=4 nx=2 be=fu,fi ga=fu,fi ps=sy,fi !Causal model ny=dependent variables nx=control variables
free be(1,2) be(1,3) be (1,4) !free=coefficients to be estimated
free ga(2,1) ga(2,2) ga(3,1) ga(3,2) ga(4,1) ga(4,2) ga(1,1)
free ps(1,1) ps(2,2) ps(3,3) ps(4,4) ps(3,2) ps(4,2) ps(4,3)
pd !To obtain a path diagram
out nd=3 sc !out= output nd=number of decimals sc=also standardized solution

*Note that the effect of Income on Satdem (ga(1,2)) has not been introduced in this syntax without correction for measurement errors.

Syntax 6.2: The LISREL syntax for the estimation of the unstandardized coefficients of the causal model with correction for measurement errors
Unstandardized causal analysis with corrections
data ni=6 no=1468 ma=cm
cm !The corrected covariance matrix
3.289
1.597 2.270
1.123 1.219 2.287
1.845 0.833 0.616 4.634
0.435 0.237 0.064 0.469 2.241
1.046 1.271 1.009 0.525 0.049 5.564
labels
satdem free critic equal lrplace inc
model ny=4 nx=2 be=fu,fi ga=fu,fi ps=sy,fi
free be(1,2) be(1,3) be (1,4)
free ga(2,1) ga(2,2) ga(3,1) ga(3,2) ga(4,1) ga(4,2) ga(1,1)
free ps(1,1) ps(2,2) ps(3,3) ps(4,4) ps(3,2) ps(4,2) ps(4,3)
pd
out nd=3 sc

The most important point is that the coefficients that have to be estimated are presented in the lines starting with ‘free’. Comparing these two inputs, we see that only the matrix with the data to be analysed has been changed. Focusing on the input for the model with correction for measurement errors, the effects will be estimated on the basis of the corrected covariance matrix in Table 6.8 (i.e. the matrix with the correction for measurement errors).

The nice feature of this approach, correcting the correlations for measurement errors before estimating the effects, is that the input for the analysis is exactly the same with and without correction for measurement errors, except for the matrix of variances and covariances that is used in the analysis. This point is illustrated in the input for the analyses with and without correction for measurement errors presented in Syntaxes 6.1 and 6.2.

However, analysing the matrix without correction for measurement errors, the program indicates that the fit of the model is not good. This suggests that the effect, ga(1,2), of the control variable Income on satisfaction with democracy has to be introduced in the model. If we do so, this model also fits well to the data and we obtain the unstandardized results presented in Table 6.9.

Table 6.9: The LISREL results of the estimation of the unstandardized coefficients of the causal model presented in Figure 6.1 with and without corrections

Continue with Stata

In Syntaxes 6.1 and 6.2, we can observe that all effects have been indicated using the Stata notation [Aco13]. We can expect variances between the disturbance terms of the evaluation of democracy questions, which are denoted in Stata as e.free*e.critic, e.free*e.equal and e.critic*e.equal. Comparing the two inputs, we see that only the matrix with the data to be analysed has been changed. Focusing on the input for the model with correction for measurement errors, the effects will be estimated on the basis of the corrected covariance matrix in Table 6.8 (i.e. the matrix corrected for measurement errors).

Syntax 6.1: The Stata syntax for the estimation of the unstandardized coefficients of the causal model without correction for measurement errors**
*Unstandardized causal analysis without corrections
clear all
ssd init satdem free critic equal lrplace inc /*variables*/
ssd set observations 1468 /*observations*/

*Covariance matrix
#delimit ;
ssd set covariances
4.633\
1.597 3.531\
1.123 1.735 3.786\
1.845 1.556 1.462 7.659\
0.732 0.237 0.064 0.469 3.286\
1.046 1.271 1.009 0.525 0.049 8.916;
#delimit cr
save ssdmatrix.dat, replace

*Unstandardized causal model
clear
use ssdmatrix.dat
ssd list
sem (satdem <- free critic equal lrplace inc) ///
(lrplace inc -> free critic equal), ///
covariance (e.free*e.critic e.free*e.equal e.critic*e.equal)
estat eqgof /*Equation-level goodness of fit*/

**Note that the effect of Income on Satdem has not been introduced in this syntax without correction for measurement errors.

Syntax 6.2: The Stata syntax for estimation of the unstandardized coefficients of the causal model with correction for measurement errors
*Unstandardized causal analysis with corrections
clear all
ssd init satdem free critic equal lrplace inc
ssd set observations 1468

*Covariance matrix input
#delimit ;
ssd set covariance /*The corrected covariance matrix*/
3.289\
1.597 2.270\
1.123 1.218 2.287\
1.845 0.833 0.616 4.634\
0.435 0.237 0.064 0.469 2.241\
1.046 1.271 1.009 0.525 0.049 5.564;
#delimit cr
save ssdmatrix.dat, replace

*Unstandardized causal model
clear
use ssdmatrix.dat
ssd list
sem (satdem <- free critic equal lrplace) ///
(lrplace inc -> free critic equal), ///
covariance(e.free*e.equal e.free*e.critic e.critic*e.equal)
estat eqgof /*Equation-level goodness of fit*/

The nice feature of this approach, correcting the correlations for measurement errors before estimating the effects, is that the input for the analysis is exactly the same with and without correction for measurement errors, except for the matrix of variances and covariances that is used in the analysis. This point is illustrated in the input for the analyses with and without correction for measurement errors presented in Syntaxes 6.1 and 6.2.

However, analysing the matrix without correction for measurement errors, the program indicates that the fit of the model is not good. This suggests that the effect of the control variable income (Inc) on satisfaction with democracy has to be introduced in the model. If we do so, this model also fits well to the data and we obtain the estimates of the unstandardized coefficients presented in Table 6.10.

Table 6.10: The Stata results of the estimation of the unstandardized coefficients of the causal model presented in Figure 6.1 with and without corrections

If we compare the unstandardized results with and without correction for measurement error, we see first of all that the model is different. After correction for measurement errors, the effects of the control variable (Inc) on satisfaction with democracy is not significantly different from zero, while, without correction for measurement errors, this effect is needed to achieve a good fit of the model. In the latter case, we say that this variable has a direct effect on satisfaction with democracy, while in the former analysis we have to conclude that there is no direct effect, only an indirect effect.

Figure 6.3: The unstandardized coefficients of the causal model for the evaluation of democracy without correction for measurement errors

Figure 6.4: The unstandardized coefficients of the causal model for the evaluation of democracy with correction for measurement errors

Furthermore, comparing Figures 6.3 and 6.4, we see that nearly all other unstandardized effects after correction for measurement error are bigger than without correction for errors. In this case, the difference is in fact a little bit smaller than it was for the standardized solution, but still substantively rather important. All significant effects are indicated by an asterisk (*) in the figures. Using this approach, we see that, in both analyses, the effect of left-right placement on freedom to criticise is not significant on the 5% significance level. The explained variance in Satdem increases from 22.7% to 46.6%3, as before.

This example illustrates again how different the results can be if one does or does not correct for measurement errors, even if the covariance matrix is used. It also shows that the analysis with correction for measurement errors is not more difficult than the analysis without correction for errors. It is only necessary to correct the covariances before starting the analysis.

Exercise 6.1

Compute the corrected covariance matrix for the variables introduced in exercise 3.1. The covariance matrix without corrections is provided in the tables below, together with the quality predictions obtained in exercise 3.1 using SQP, the standardized cmv obtained in exercise 4.3 and the descriptive statistics of the variables.

Quality predictions obtained in exercise 3.1 using SQP:

Covariance matrix (n = 1801):

Standardized cmv:

Descriptive statistics of the variables:

Solution

Firstly, we have to compute the unstandardized cmv for the variables measured by a common method in order to correct the covariances between these variables. This applies to the variables Economy, Culture and Better, which use 11-point, item-specific scales. The computation of the standardized cmv was already done in exercise 4.3. With these results, we are able to compute the unstandardized cmv based on the following formula:

Unstandardized cmv = (Standardized cmv) sisj
unstandardized cmvB40,B38 = 0.094 * 1.817 * 1.908 = 0.327
unstandardized cmvB40,B39 = 0.110 * 1.817 * 1.942 = 0.388
unstandardized cmvB38,B39 = 0.117 * 1.908 * 1.942 = 0.433

Secondly, we have to subtract the unstandardized cmv from the covariances corrected for common method variance:

correctedcovB40,B38 = 1.850 – 0.327 = 1.523
correctedcovB40,B39 = 1.966 – 0.388 = 1.578
correctedcovB38,B39 = 1.965 – 0.433 = 1.532

Thirdly, correct the variances on the diagonal by removing the error variance or putting the product of the quality obtained from SQP on the diagonal:

correctedvarB37 = 0.721 * 0.763 = 0.550
correctedvarB40 = 3.300 * 0.639 = 2.109
correctedvarB38 = 3.641 * 0.702 = 2.556
correctedvarB39 = 3.770 * 0.641 = 2.417

By imputing the corrected variances on the diagonal from the table above, the covariance matrix corrected for measurement errors has been obtained.

Exercise 6.2

Repeat the estimation of the causal model for the same unstandardized variables. The covariance matrix with corrections obtained in exercise 6.1 is presented in the table below. Furthermore, the covariance matrix without corrections was provided in the previous exercise. Use this information to compute, either in LISREL or Stata, the results for the analysis of the explanation of the opinion about immigration by people from outside Europe to the Netherlands with and without correction for measurement errors presented in the next figure.

The model to be estimated is:

Causal model for attitudes towards immigration

Covariance matrix corrected for measurement errors:

Solution for LISREL users

  1. LISREL syntax for the estimation of the unstandardized causal model without corrections for measurement errors:
    Unstandardized causal analysis without corrections
    data ni=4 no=1801 ma=cm
    cm
    0.721
    -0.542 3.300
    -0.652 1.850 3.641
    -0.561 1.966 1.965 3.770
    labels
    impcntr imwbcnt imbgeco imueclt
    model ny=2 nx=2 be=fu,fi ga=fu,fi ps=sy,fi
    free be(1,2)
    free ga(1,1) ga(1,2) ga(2,1) ga(2,2)
    free ps(1,1) ps(2,2)
    pd
    out nd=3 sc
  2. LISREL syntax for the estimation of the unstandardized causal model with corrections for measurement errors:
    Unstandardized causal analysis with corrections
    data ni=4 no=1801 ma=cm
    cm
    0.550
    -0.542 2.109
    -0.652 1.523 2.556
    -0.561 1.578 1.532 2.417
    labels
    impcntr imwbcnt imbgeco imueclt
    model ny=2 nx=2 be=fu,fi ga=fu,fi ps=sy,fi
    free be(1,2)
    free ga(1,1) ga(1,2) ga(2,1) ga(2,2)
    free ps(1,1) ps(2,2)
    pd
    out nd=3 sc

Solution for Stata users

  1. Stata syntax for the estimation of the unstandardized causal model without corrections for measurement errors:
    *Unstandardized causal model without correction for measurement errors
    clear all
    ssd init impcntr imwbcnt imbgeco imueclt
    ssd set observations 1801
    *Covariance matrix
    #delimit ;
    ssd set covariances
    0.721\
    -0.542 3.300\
    -0.652 1.850 3.641\
    -0.561 1.966 1.965 3.770;
    #delimit cr
    save ssdmatrix.dat, replace
    *Causal model
    clear
    use ssdmatrix.dat
    ssd list
    sem (impcntr <- imwbcnt imbgeco imueclt) ///
    (imbgeco imueclt -> imwbcnt)
    estat eqgof
  2. Stata syntax for the estimation of the unstandardized causal model with corrections for measurement errors:
    *Unstandardized causal model with correction for measurement errors
    clear all
    ssd init impcntr imwbcnt imbgeco imueclt
    ssd set observations 1801
    *Covariance matrix
    #delimit ;
    ssd set covariances
    0.550\
    -0.542 2.109\
    -0.652 1.523 2.556\
    -0.561 1.578 1.532 2.417;
    #delimit cr
    save ssdmatrix.dat, replace
    *Causal model
    clear
    use ssdmatrix.dat
    ssd list
    sem (impcntr <- imwbcnt imbgeco imueclt) ///
    (imbgeco imueclt -> imwbcnt)
    estat eqgof

Solution

The figure at the top presents the results for the unstandardized causal model without corrections. Again, we see from this model that all effects are significant. However, compared with the standardized results obtained in exercise 5.2, we can see that the effects are now smaller. The second figure shows the results for the unstandardized causal model with corrections. Comparing these two models, we see that the increase in the effects is small. This was explained in the last chapter. The variance explained with and without corrections for the unstandardized causal model is equal to the variance explained in the standardized causal model.

Go to next chapter >>

Footnotes

References